Создание точки восстановления системы при старте системы

Создание точки восстановления системы при старте системы

Создание точки восстановления системы при старте системы без использования апплета "Защита системы".

Если Вам необходимо создать точку восстановления системы при старте системы не используя апплет "Защита системы", то Вы можете создать скрипт с содержимым указанным ниже и добавить ярлык для него в автозагрузку.Создание точки восстановления системы при старте системы

Для того чтобы создать скрипт:

  1. Скопируйте выбранный Вами код в любой текстовый редактор (например, Блокнот).
  2. Нажмите Ctrl + S и сохраните файл с любым именем и расширением .vbs в любой папке (Например, на диске C:)
  3. Создайте ярлык для созданного Вами файла скрипта в Автозагрузку
  • Для того чтобы добавить ярлык скрипта в автозагрузку пройдите по пути: C:\Users\VINCE\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup и поместите ярлык в папку Startup, но так как папка AppData  скрытая не все смогут ее найти, поэтому можно добавить ярлык в автозагрузку другим способом, для этого откройте Пуск и раскройте список Все программы или Программы и найдите в нем папку Автозагрузка, нажмите по ней правой кнопкой мыши и выберите Открыть, после того как откроется окно просто переместите в открытое окно созданный Вами ярлык.

В фоновом режиме без вывода сообщений и окон:

If WScript.Arguments.Count = 0 Then
Set objShell = CreateObject("Shell.Application")
objShell.ShellExecute "wscript.exe", Chr(34) & WScript.ScriptFullName & Chr(34) & " Run", , "runas", 1
Else
GetObject("winmgmts:\\.\root\default:Systemrestore").CreateRestorePoint "Текущая Точка Восстановления", 0, 100
End If

С выводом окна для введения наименования для точки восстановления:

If GetOS = "Windows 7" Then
If WScript.Arguments.length =0 Then
Set objShell = CreateObject("Shell.Application")
objShell.ShellExecute "wscript.exe", """" & _
WScript.ScriptFullName & """" & " uac","", "runas", 1
Else
CreateSRP
End If
End If

Sub CreateSRP

msg = "Точка восстановления успешно создана." & vbCR
msg = msg & "" & vbCR
msg = msg & "Дата и время создания: " & Date & " " & Time

Set SRP = getobject("winmgmts:\\.\root\default:Systemrestore")
sDesc = ""
sDesc = InputBox ("Введите описание для точки восстановления.", "Создание точки восстановления системы","")
If Trim(sDesc) <> "" Then
sOut = SRP.createrestorepoint (sDesc, 0, 100)

If sOut <> 0 Then
WScript.echo "Error " & sOut & _
": Невозможно создать точку восстановления системы."
Else
MsgBox msg

End If
End If
End Sub

Function GetOS
Set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & _
".\root\cimv2")
Set colOS = objWMI.ExecQuery("Select * from Win32_OperatingSystem")
For Each objOS in colOS

If instr(objOS.Caption, "Windows 7") Then
GetOS = "Windows 7"

End If
Next
End Function


Каждый раз при включении компьютера будет создаваться точка восстановления системы что снизит риск потери данных и работоспособности системы так как в случае сбоя можно будет легко восстановить систему.

Поделитесь в соц сетях...
Share on VK
VK
Share on Facebook
Facebook
Tweet about this on Twitter
Twitter
Share on LinkedIn
Linkedin
Email this to someone
email

Добавить комментарий

Ваш e-mail не будет опубликован. Обязательные поля помечены *